pxJCreateCylindrical%(body1%, body2%, x#, y#, z#, nx#, ny#, nz#, min_limit#, max_limit#)

Параметры

body1%, body2% - соединяемые тела
x#, y#, z# - координаты соединения
nx#,ny#,nz# - координаты вектора направления оси
min_limit# - минимальное растояние между телами
max_limit# - максимальное растояние между телами

Описание

Создает соединение типа спицы.
Внимание - соединение не создается между статическим (с массой 0) и динамическим телами.
Для того чтоб получить шарнир, привязанный к статике, нужно вместо body1 указать 0.

Смотрите так же

Пример

;Пример применения функции
;pxJCreateCylindrical

;в примере нам понадобится несколько однотипных тел
Type Px_Cylinder
    Field body%
    Field mesh%
End Type

Graphics3D 800, 600, 32, 2
SetBuffer BackBuffer()

;Создаем физический мир, устанавливаем гравитацию.
pxCreateWorld(1) ;У нас будет поверхность
pxSetGravity(0, -10, 0)

camera=CreateCamera()
light=CreateLight()

PositionEntity camera,0,20,-40
RotateEntity camera,30,0,0

plane=CreatePlane() ;Визуализируем поверхность
EntityColor plane,0,100,200
EntityAlpha plane,0.5

mir = CreateMirror () ;Чуть украсим зеркалом

;Добавим объектов к сцене
For n = 1 to Rnd(10,40)

    ocu.Px_Cylinder = New Px_Cylinder
    ocu\mesh = CreateCylinder() ;Создаем визуальное отображение
    ScaleEntity ocu\mesh,1,3,1 ;зададим размер
    EntityColor ocu\mesh,Rand(0,255), Rand(0,255), Rand(0,255) ;и цвет

    ocu\body=pxCreateCylinder( 1, 3, 8, 1) ;Создаем физический объект
    pxSetPosition(ocu\body,Rand(-20,20),40,Rand(-10,30)) ;размещаем случайным образом
    pxSetRotation(ocu\body,Rand(-50,50),Rand(-50,50),Rand(-50,50))

Next

body1 = pxCreateCube( 1, 1, 1, 20)
pxSetPosition(body1,0,3,0)
mesh1 = CreateCube()
EntityColor mesh1,255,0,0 ;цвет - красный

body2 = pxCreateCube( 1, 1, 1, 20)
pxSetPosition(body2,0,9,0)
mesh2 = CreateCube()
EntityColor mesh2,0,255,0 ;цвет - зеленый

; ------------ Применяем pxJCreateCylindrical
;Создаем соединение "спица"
pxJCreateCylindrical(body1, body2, 0, 6, 0, 0, 1, 0, -20, 20)

;Создаем пружину
pxCreateSpringAndDamperEffector(body1, body2)

;Основной цикл программы
While Not KeyDown(1) ;Пока не нажат ESC

;обсчитываем физический мир
    RenderPhysic(60,0)

;Применяем силы в зависимости от нажатой клавиши
    If KeyDown(200) pxAddForce(body1,0,0,2000,0)
    If KeyDown(208) pxAddForce(body1,0,0,-2000,0)
    If KeyDown(205) pxAddForce(body1,2000,0,0,0)
    If KeyDown(203) pxAddForce(body1,-2000,0,0,0)

;Обновим положения всех объектов
    For ocu.Px_Cylinder = Each Px_Cylinder
     pxSetEntity(ocu\mesh, ocu\body)
    Next

    pxSetEntity(mesh1,body1)
    pxSetEntity(mesh2,body2)

;UpdateWorld

    RenderWorld
    Text 10,10,"Для кубиков можно применять клавиши управления"
    Flip
    Wend

End

К содержанию

Нажмите здесь чтобы увидеть последнюю версию этой странички в режиме online.